PowerBI技巧：制作动态坐标轴

前几天的文章中介绍了如何制作动态的分析指标，这篇进行文章再介绍一下如何制作动态的坐标轴。

假设要分析的数据为销售额，分别从产品和地区两个维度进行分析，要实现的效果是，如果选择的是产品，则坐标轴是各个产品的名称，对应的是各个产品的销售额；如果选择的是地区，则坐标轴为城市，展现的是各个城市的销售额。

要达到这样的效果，我们首先需要把城市名称和产品名称整合到一起，直接用DAX来进行整合出一张表，

坐标轴指标表 =

VAR table1=SELECTCOLUMNS(ADDCOLUMNS(VALUES('产品'[产品名称]),"指标","产品"),"指标",[指标],"指标明细",[产品名称])

VAR table2=SELECTCOLUMNS(ADDCOLUMNS(VALUES('客户'[客户城市]),"指标","地区"),"指标",[指标],"指标明细",[客户城市])

RETURN UNION(table1,table2)

这个度量值主要是ADDCOLUMNS函数与SELECTCOLUMNS函数的密切配合，先用ADDCOLUMNS函数在提取的维度表上添加一列该维度的属性，返回带属性值的表；然后用SELECTCOLUMNS命名字段名，返回两个相同字段名的表，最后用UNION把两个表合并成一张表。

根据上一篇文章关于DAX表函数的介绍，ADDCOLUMNS函数与SELECTCOLUMNS都是表函数，它们的第一个参数是表，返回的也是一张表，这是理解这两个函数的关键。

创建的坐标轴指标表如下：

指标表创建好了，然后用该表中的[指标明细]作为坐标轴，并按[指标]字段做个切片器，这样当选择产品的时候，和产品对应的就是产品类别,地区也同理。

把销售额作为值，生成一个柱形图看看是什么样的，

可以看到通过产品和地区的筛选，坐标轴确实动态切换了，但是数据却明显异常，没有按照上下文进行计算，这是什么原因呢？

其实看到图中的数据都是汇总数，就很容易想到，刚才生成的坐标轴指标表，没有和订单表建立关系，因为订单表中的地区和城市分属不同的字段，无法同时连接。

如果利用指标明细和订单表中的产品类别建立关系，按产品类别作为坐标轴可以正常显示，但是按地区就没法显示数据了，因为地区和订单表没有建立任何关系。

为了解决这个问题，这里要用到一个非常重要的函数：TREATAS，它的作用是在两个表之间构建虚拟关系。

新建度量值如下：

分析数据 =

SWITCH(TRUE(),

SELECTEDVALUE('坐标轴指标表'[指标])="产品",CALCULATE([销售额],TREATAS(VALUES('坐标轴指标表'[指标明细]),'产品'[产品名称])),

SELECTEDVALUE('坐标轴指标表'[指标])="地区",CALCULATE([销售额],TREATAS(VALUES('坐标轴指标表'[指标明细]),'客户'[客户城市]))

)

这个度量值先判断切片器的选择，如果选择的是产品，则用TREATAS函数在坐标轴明细表与产品表之间构建虚拟关系，这样[销售额]就可以正常筛选计算了；选择地区的时候亦然。

效果如下，

正是想要的结果。

不过当切片器不选择或者多选的时候，又出现问题了，

坐标轴竟然同时显示了城市和产品，这样的比较显然没有任何意义，我们继续优化。

为了避免多选或者不选的问题，这里利用HASONEFILTER函数进行判断，HASONEFILTER函数的含义是判断是否存在单一的筛选器。

优化思路是：如果单选坐标轴指标，就是单一的筛选器，按照上面的度量值正常显示；如果不存在筛选器，或者存在多个筛选器，就上报一个错误。

分析指标的度量值修改如下，

分析数据1 =

IF(HASONEFILTER('坐标轴指标表'[指标]),

SWITCH(TRUE(),

SELECTEDVALUE('坐标轴指标表'[指标])="产品",CALCULATE([销售额],TREATAS(VALUES('坐标轴指标表'[指标明细]),'产品'[产品名称])),

SELECTEDVALUE('坐标轴指标表'[指标])="地区",CALCULATE([销售额],TREATAS(VALUES('坐标轴指标表'[指标明细]),'客户'[客户城市]))

),

ERROR("数据错误，请单选坐标轴指标！")

)

这样设置以后，效果如下，

这里利用ERROR函数故意上报一个错误，并提示报表使用者错误的原因和解决方式，

至此，充分考虑了各种情况，利用DAX巧妙构建度量值，实现了坐标轴的动态切换。